参考: 同じ構成をTerraformで作る

ここまでのハンズオンでは、CloudFormation + マネジメントコンソール + AWS CLIを使って段階的にBlue/Greenデプロイの環境を構築しました。参考として、フェーズ4までを含めた最終形(自動テスト + 手動承認)をTerraformで一括構築する構成も紹介します。

Terraformで管理すると、今回ハンズオンで手動作成したALB・ターゲットグループ・ECSサービス・DynamoDB・Lambda・IAMロールまで1つのコードベースで管理でき、環境の再構築や複製、変更の追跡が容易になります。

1. Terraform AWS Providerのバージョン

本セクションのコードは、AWS Provider v6.40以降を前提としています。ECSのBlue/Green戦略をTerraformで定義するためのdeployment_configuration.strategy = "BLUE_GREEN"や、ライフサイクルフック用のlifecycle_hookブロック、load_balancer.advanced_configurationブロックは比較的新しい機能です。詳しくはTerraform AWS Provider 公式ドキュメント(aws_ecs_service)に記載があります。

2. コードのダウンロード

以下のボタンから、Terraformコード一式をダウンロードしてください。

3. ファイル構成

ZIPを解凍すると、以下の構成のフォルダができます。

terraform-bg-handson/
├── provider.tf          # Terraformとプロバイダのバージョン指定
├── variables.tf         # 入力変数(リージョン・プレフィックス)
├── network.tf           # VPC、サブネット、IGW、ルートテーブル、セキュリティグループ
├── ecr.tf               # ECRリポジトリ
├── iam.tf               # 各種IAMロール(タスク実行・インフラ・Lambda・フック呼び出し)
├── logs.tf              # CloudWatch Logs
├── alb.tf               # ALB、ターゲットグループ、リスナー、リスナールール
├── dynamodb.tf          # 承認レコード用DynamoDBテーブル
├── lambda.tf            # Lambda関数(自動テスト + 承認ステータス確認)
├── ecs.tf               # ECSクラスタ、タスク定義、サービス(Blue/Green設定)
├── outputs.tf           # 出力値(ALBのDNS名、ECRのURI、DynamoDBテーブル名など)
└── lambda/
    └── e2e_test/
        └── lambda_function.py   # メインLambda(自動テスト + 承認ステータス確認)
💡 ポイント
Terraformはファイル分割のルールを持たないため、上記のようにリソースの種類ごとに.tfファイルを分けるのがよくあるスタイルです。小規模な構成では1ファイルにまとめても動きますが、数が増えてくると役割ごとに分けたほうが可読性が上がります。

4. ポイントとなるコードの解説

すべてのファイルをここで解説すると長くなるため、Blue/Greenデプロイメントならではの部分に絞って解説します。他のファイル(VPCやIAMロールなど)は標準的な書き方なので、実際のコードを読みながら確認してください。

4.1 ALBのリスナールール

ECSのBlue/Green戦略では、本番トラフィックとテストトラフィックを別々のリスナールールとして明示的に定義する必要があります。ハンズオン本編と同じく、ポート80の単一リスナーに「テストルール(優先度1: ヘッダー条件)」と「本番ルール(優先度2: 全パス)」の2つを並べます。Terraformではaws_lb_listener_ruleを2つ定義し、それぞれのARNをECSサービスに渡します。

# テストリスナールール(優先度1: 最優先で評価)
# X-Test-Traffic: true ヘッダー付きリクエストのみGreenへ転送する
resource "aws_lb_listener_rule" "test" {
  listener_arn = aws_lb_listener.main.arn
  priority     = 1

  action {
    type             = "forward"
    target_group_arn = aws_lb_target_group.green.arn
  }

  condition {
    http_header {
      http_header_name = "X-Test-Traffic"
      values           = ["true"]
    }
  }
}

# 本番リスナールール(優先度2: テストルールにマッチしないリクエストを処理)
resource "aws_lb_listener_rule" "production" {
  listener_arn = aws_lb_listener.main.arn
  priority     = 2

  action {
    type             = "forward"
    target_group_arn = aws_lb_target_group.blue.arn
  }

  condition {
    path_pattern {
      values = ["/*"]
    }
  }
}

テストルールではX-Test-Traffic: trueヘッダー付きのリクエストのみをGreen用ターゲットグループへ転送し、本番ルールではそれ以外のすべてのリクエストをBlue用ターゲットグループへ転送します。これらのリスナールールのARNを、後述のECSサービスのadvanced_configurationでproduction_listener_ruleとtest_listener_ruleとして指定します。

💡 ポイント
ハンズオン本編ではマネジメントコンソールで「本番ルール=デフォルトルール、テストルール=優先度1」という設定にしましたが、ECS native Blue/Greenのproduction_listener_ruleにはリスナールールのARNが必要なため、Terraformでは本番ルールも明示的なaws_lb_listener_ruleとして定義しています。リスナーのデフォルトアクションはfixed-responseの404にしておき、どちらのルールにもマッチしなかった場合のフォールバックとします。

4.2 Lambda関数の自動パッケージング

Lambda関数のコードはlambda/e2e_test/lambda_function.pyに置き、Terraformのarchive_fileデータソースで自動的にZIP化します。複数Lambdaへ拡張する場合に備えて、関数名ごとのディレクトリ構成にしています。

data "archive_file" "e2e_test" {
  type        = "zip"
  source_dir  = "${path.module}/lambda/e2e_test"
  output_path = "${path.module}/build/e2e_test.zip"
}

resource "aws_lambda_function" "e2e_test" {
  function_name    = "${var.project}-e2e-test"
  role             = aws_iam_role.lambda.arn
  handler          = "lambda_function.lambda_handler"
  runtime          = "python3.13"
  timeout          = 60
  filename         = data.archive_file.e2e_test.output_path
  source_code_hash = data.archive_file.e2e_test.output_base64sha256

  environment {
    variables = {
      ALB_DNS_NAME    = aws_lb.main.dns_name
      APPROVALS_TABLE = aws_dynamodb_table.approvals.name
    }
  }
}

source_code_hashにarchive_fileのハッシュ値を指定しているのがポイントです。これによりlambda_function.pyを書き換えると次のterraform applyでLambdaが自動的に更新されます。手動でZIP化する必要がないため、コードの修正からデプロイまでがスムーズです。

また、environment.variablesでALBのDNS名とDynamoDBテーブル名を環境変数として注入しています。ハンズオン本編でもALB_DNS_NAMEはマネジメントコンソールから手動設定しましたが、Terraformではaws_lb.main.dns_nameを直接参照することで、ALBのDNS名がLambdaへ自動で連携されます。APPROVALS_TABLEについてはハンズオン本編でコード内にハードコードしていましたが、Terraformで管理する場合は環境変数経由で渡すほうが、テーブル名をコード変更なしに切り替えられるため柔軟です。

4.3 ECSサービスのBlue/Green設定

本セクションの核心部分です。ECSサービスにdeployment_configurationブロックでBlue/Green戦略とライフサイクルフックを定義し、load_balancerブロック配下のadvanced_configurationでBlue/Green用のターゲットグループ・リスナールール情報を渡します。

resource "aws_ecs_service" "main" {
  name            = "${var.project}-service"
  cluster         = aws_ecs_cluster.main.id
  task_definition = aws_ecs_task_definition.main.arn
  desired_count   = 1
  launch_type     = "FARGATE"

  deployment_configuration {
    strategy             = "BLUE_GREEN"
    bake_time_in_minutes = 30

    lifecycle_hook {
      hook_target_arn  = aws_lambda_function.e2e_test.arn
      role_arn         = aws_iam_role.lifecycle_hook.arn
      lifecycle_stages = ["TEST_TRAFFIC_SHIFT"]
    }
  }

  load_balancer {
    target_group_arn = aws_lb_target_group.blue.arn
    container_name   = "app"
    container_port   = 8000

    advanced_configuration {
      alternate_target_group_arn = aws_lb_target_group.green.arn
      production_listener_rule   = aws_lb_listener_rule.production.arn
      test_listener_rule         = aws_lb_listener_rule.test.arn
      role_arn                   = aws_iam_role.ecs_infrastructure.arn
    }
  }

  # ...network_configuration など...
}

コードを解説します。

  deployment_configuration {
    strategy             = "BLUE_GREEN"
    bake_time_in_minutes = 30

strategy = "BLUE_GREEN"で、このサービスにBlue/Greenデプロイメントを適用します。bake_time_in_minutesは、本番切り替え後に旧環境(Blue)を残しておく時間です。ハンズオンと同じく30分に設定しています。

    lifecycle_hook {
      hook_target_arn  = aws_lambda_function.e2e_test.arn
      role_arn         = aws_iam_role.lifecycle_hook.arn
      lifecycle_stages = ["TEST_TRAFFIC_SHIFT"]
    }

ライフサイクルフックの設定です。TEST_TRAFFIC_SHIFTステージでLambda関数を呼び出すことで、本番切り替え前にGreen環境へ自動テストを実行します。テストがFAILEDを返せばECSが自動的にロールバックするため、バグ入りのバージョンが本番に出る前に止められます。

  load_balancer {
    target_group_arn = aws_lb_target_group.blue.arn
    ...
    advanced_configuration {
      alternate_target_group_arn = aws_lb_target_group.green.arn
      production_listener_rule   = aws_lb_listener_rule.production.arn
      test_listener_rule         = aws_lb_listener_rule.test.arn
      role_arn                   = aws_iam_role.ecs_infrastructure.arn
    }
  }

load_balancerブロックのtarget_group_arnには現在(初期状態で)本番に紐づくターゲットグループ(Blue)を指定します。advanced_configurationでBlue/Green専用の情報を追加しています。

  • alternate_target_group_arn: デプロイ時に切り替えるもう片方のターゲットグループ(Green)
  • production_listener_rule: 本番トラフィックを振り分けているリスナールールのARN
  • test_listener_rule: テストトラフィック用のリスナールールのARN
  • role_arn: ECSがALBのターゲットグループを操作するためのIAMロール(AmazonECSInfrastructureRolePolicyForLoadBalancersをアタッチ済み)

この設定により、ECSはデプロイ時にどのリスナールールを書き換えて、どのターゲットグループを入れ替えるかを自動的に判断できるようになります。

4.4 承認フロー用のDynamoDB

フェーズ4の手動承認を支えるDynamoDBテーブルもTerraformで一緒に作成します。DynamoDBは承認レコードの永続化を担い、承認操作は本セクションと同様に DynamoDBコンソールから直接status属性を書き換える 形を取ります。

resource "aws_dynamodb_table" "approvals" {
  name         = "${var.project}-approvals"
  billing_mode = "PAY_PER_REQUEST"
  hash_key     = "deployment_id"

  attribute {
    name = "deployment_id"
    type = "S"
  }
}

DynamoDBテーブルはbilling_mode = "PAY_PER_REQUEST"にしているため、使った分だけの従量課金でキャパシティの事前設定が不要です。本セクションのような低頻度アクセスのワークロードに向いています。

💡 ポイント
本セクションでは承認をシンプルにDynamoDBコンソール直接更新で行う構成にしていますが、実業務では誤操作防止・最小権限の付与・承認UIの拡張性・監査証跡の自動化の観点から、承認専用のLambda関数を別途用意し、その関数経由でDynamoDBを更新する構成が望ましい です。Lambdaを増やす場合は、lambda.tfにもう1つaws_lambda_functionリソースを追加し、iam.tfにDynamoDBのUpdateItem権限を持つ専用ロールを定義する形になります。

5. 使い方

ダウンロードしたフォルダ内で、以下のコマンドを順に実行します。

まず、以下のコマンドで、Terraform がインストールされていることを確認します。

terraform --version

以下のように Terraform のバージョンが表示されれば、インストールは確認できています。

Terraform vX.X.X
on darwin_arm64

バージョンが表示されない場合は、Terraformのインストール を先に実施してください。

インストールが確認できたら、初回セットアップを行います。

terraform init

実行計画を確認します。

terraform plan

問題がなければ適用します。

terraform apply

terraform applyが完了すると、ハンズオンと同じリソース一式(VPC・ALB・ECS・DynamoDB・Lambda・IAM)が作成されます。あとはハンズオン本編と同じように、ECRへイメージをプッシュしてから、ECSコンソールで新しいデプロイの強制を実行すれば、Blue/Greenデプロイメントとライフサイクルフックによる自動テスト、そして手動承認フローまで動作します。

承認/却下はハンズオン本編と同様、DynamoDBコンソールでbg-handson-approvalsテーブルの該当レコードを開き、status属性をapprovedまたはrejectedに書き換える形で行います。

リソースを削除する際は、以下のコマンド一発で一括削除できます。

terraform destroy

CloudFormationやマネジメントコンソールでの個別削除と比べ、削除漏れが起きにくいのもTerraformで管理する大きなメリットです。