baseモジュールの作成

メインインフラの準備が整ったので、次にアプリケーションを動かすためのネットワークやデータベースなどの基盤リソースを作成します。VPC、サブネット、セキュリティグループ、RDSなどをbaseモジュールとしてまとめて管理します。

このモジュールで作成されるリソースは以下のとおりです。

種類 リソース名 用途
Route53 ホストゾーン test-noteapp-zone カスタムドメインのDNSレコードを管理
VPC test-noteapp-vpc ネットワークの基盤
パブリックサブネット test-noteapp-public-1, 2 ALB、NATゲートウェイを配置
プライベートサブネット test-noteapp-private-1, 2 ECS Fargate、RDSを配置
インターネットゲートウェイ test-noteapp-igw VPCからインターネットへの出入口
NATゲートウェイ test-noteapp-nat-gw プライベートサブネットからのインターネットアクセス
セキュリティグループ test-noteapp-alb-sg ALBのインバウンドルール(HTTPS/HTTP)
セキュリティグループ test-noteapp-api-sg ECSタスクのインバウンドルール(ポート8000)
セキュリティグループ test-noteapp-rds-sg RDSのインバウンドルール(ポート3306)
RDS test-noteapp-db MySQLデータベース
ECR test-noteapp-api APIのコンテナイメージを格納
CloudWatch Logs /ecs/test-noteapp-api ECSタスクのログを収集

1. コードの記載

ここでは、VPC、サブネット、インターネットゲートウェイ、ルートテーブル、セキュリティグループ、RDSを一つのモジュールとして作成します。modules/base/ディレクトリの各ファイルにコードを記述していきます。

1.1 variables.tf

modules/base/variables.tfに以下の内容を記述します。

variable "project_name" {
  description = "プロジェクト名"
  type        = string
}

variable "vpc_cidr" {
  description = "VPCのCIDRブロック"
  type        = string
  default     = "10.0.0.0/16"
}

variable "availability_zones" {
  description = "使用するアベイラビリティゾーン"
  type        = list(string)
}

variable "db_name" {
  description = "データベース名"
  type        = string
}

variable "db_username" {
  description = "マスタユーザ名"
  type        = string
}

variable "db_password" {
  description = "マスタパスワード"
  type        = string
  sensitive   = true
}

variable "db_instance_class" {
  description = "RDSインスタンスクラス"
  type        = string
  default     = "db.t3.micro"
}

variable "domain_name" {
  description = "カスタムドメイン名"
  type        = string
}

コードを解説します。

project_name

variable "project_name" {
  description = "プロジェクト名"
  type        = string
}

リソース名のプレフィックスとして使用します。test-noteappが渡されると、VPCはtest-noteapp-vpc、ALBはtest-noteapp-api-albのような命名になります。

vpc_cidr / availability_zones

variable "vpc_cidr" {
  default     = "10.0.0.0/16"
}

variable "availability_zones" {
  type        = list(string)
}

vpc_cidrは、VPCに割り当てるIPアドレス範囲を定義する設定です。デフォルトの10.0.0.0/16で約65,000個のIPアドレスを確保できます。

availability_zonesは、マルチAZ構成で使用するアベイラビリティゾーンのリストです。["ap-northeast-1a", "ap-northeast-1c"]のように指定します。

RDS関連の変数

variable "db_password" {
  type        = string
  sensitive   = true
}

variable "db_instance_class" {
  default     = "db.t3.micro"
}

db_name、db_username、db_password、db_instance_classの4つです。

sensitiveは、変数の値をterraform planやterraform applyの出力に表示するかどうかを制御する設定です。trueにすることで、パスワードなどの機密情報がターミナルに表示されることを防ぎます。

db_instance_classはデフォルトでdb.t3.micro(検証用の最小構成)を使用します。

domain_name

variable "domain_name" {
  description = "カスタムドメイン名"
  type        = string
}

カスタムドメイン名(例: example.com)です。この値を基に、Route53ホストゾーンの作成を行います。

📝 環境側とモジュール側で variables.tf が分かれている理由
environments/test/variables.tf と modules/base/variables.tf の両方に db_password など同じ名前の変数が登場します。一見すると二重定義に見えますが、これはTerraformのモジュールの仕組み上、必要な構造です。environments/test/variables.tf は環境ごとに「何の値を受け取るか」を宣言する場所(terraform.tfvars から値を受け取る入口)で、modules/base/variables.tf はモジュールが「どんな値を受け取れるか」を定義する場所(関数の引数宣言のようなもの)です。プログラミングに例えると、モジュール側の variables.tf は関数の引数定義、環境側の variables.tf はその関数を呼び出すときに渡す値の宣言にあたります。値は terraform.tfvars → 環境側 variables.tf(または locals)→ main.tf の module "base" { ... } 呼び出し → モジュール側 variables.tf という順番で受け渡されていきます。この流れがTerraformでは必須のため、環境側とモジュール側の両方に変数定義が必要になります。

1.2 main.tf

modules/base/main.tfに以下の内容を記述します。

# =============================================================================
# ネットワーク
# =============================================================================

# VPC
resource "aws_vpc" "main" {
  cidr_block           = var.vpc_cidr
  enable_dns_hostnames = true
  enable_dns_support   = true

  tags = {
    Name = "${var.project_name}-vpc"
  }
}

# インターネットゲートウェイ
resource "aws_internet_gateway" "main" {
  vpc_id = aws_vpc.main.id

  tags = {
    Name = "${var.project_name}-igw"
  }
}

# パブリックサブネット
resource "aws_subnet" "public" {
  count = length(var.availability_zones)

  vpc_id                  = aws_vpc.main.id
  cidr_block              = cidrsubnet(var.vpc_cidr, 8, count.index)
  availability_zone       = var.availability_zones[count.index]
  map_public_ip_on_launch = true

  tags = {
    Name = "${var.project_name}-public-${count.index + 1}"
  }
}

# プライベートサブネット
resource "aws_subnet" "private" {
  count = length(var.availability_zones)

  vpc_id            = aws_vpc.main.id
  cidr_block        = cidrsubnet(var.vpc_cidr, 8, count.index + 10)
  availability_zone = var.availability_zones[count.index]

  tags = {
    Name = "${var.project_name}-private-${count.index + 1}"
  }
}

# パブリックルートテーブル
resource "aws_route_table" "public" {
  vpc_id = aws_vpc.main.id

  route {
    cidr_block = "0.0.0.0/0"
    gateway_id = aws_internet_gateway.main.id
  }

  tags = {
    Name = "${var.project_name}-public-rt"
  }
}

# パブリックサブネットとルートテーブルの関連付け
resource "aws_route_table_association" "public" {
  count = length(var.availability_zones)

  subnet_id      = aws_subnet.public[count.index].id
  route_table_id = aws_route_table.public.id
}

# NATゲートウェイ用のElastic IP
resource "aws_eip" "nat" {
  domain = "vpc"

  tags = {
    Name = "${var.project_name}-nat-eip"
  }
}

# NATゲートウェイ(パブリックサブネットに配置)
resource "aws_nat_gateway" "main" {
  allocation_id = aws_eip.nat.id
  subnet_id     = aws_subnet.public[0].id

  tags = {
    Name = "${var.project_name}-nat-gw"
  }
}

# プライベートルートテーブル
resource "aws_route_table" "private" {
  vpc_id = aws_vpc.main.id

  route {
    cidr_block     = "0.0.0.0/0"
    nat_gateway_id = aws_nat_gateway.main.id
  }

  tags = {
    Name = "${var.project_name}-private-rt"
  }
}

# プライベートサブネットとルートテーブルの関連付け
resource "aws_route_table_association" "private" {
  count = length(var.availability_zones)

  subnet_id      = aws_subnet.private[count.index].id
  route_table_id = aws_route_table.private.id
}

# =============================================================================
# ドメイン・証明書
# =============================================================================

# Route53ホストゾーンの作成
resource "aws_route53_zone" "main" {
  name = var.domain_name

  tags = {
    Name = "${var.project_name}-zone"
  }
}

# =============================================================================
# セキュリティグループ
# =============================================================================

# ALB用セキュリティグループ
resource "aws_security_group" "alb" {
  name        = "${var.project_name}-alb-sg"
  description = "Security group for ALB"
  vpc_id      = aws_vpc.main.id

  ingress {
    description = "HTTPS from Internet"
    from_port   = 443
    to_port     = 443
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  ingress {
    description = "HTTP from Internet (redirect to HTTPS)"
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = {
    Name = "${var.project_name}-alb-sg"
  }
}

# API用セキュリティグループ
resource "aws_security_group" "api" {
  name        = "${var.project_name}-api-sg"
  description = "Security group for API containers"
  vpc_id      = aws_vpc.main.id

  ingress {
    description     = "HTTP from ALB"
    from_port       = 8000
    to_port         = 8000
    protocol        = "tcp"
    security_groups = [aws_security_group.alb.id]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = {
    Name = "${var.project_name}-api-sg"
  }
}

# RDS用セキュリティグループ
resource "aws_security_group" "rds" {
  name        = "${var.project_name}-rds-sg"
  description = "Security group for RDS"
  vpc_id      = aws_vpc.main.id

  ingress {
    description     = "MySQL from API containers"
    from_port       = 3306
    to_port         = 3306
    protocol        = "tcp"
    security_groups = [aws_security_group.api.id]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = {
    Name = "${var.project_name}-rds-sg"
  }
}

# =============================================================================
# RDS
# =============================================================================

# DBサブネットグループ
resource "aws_db_subnet_group" "main" {
  name       = "${var.project_name}-db-subnet-group"
  subnet_ids = aws_subnet.private[*].id

  tags = {
    Name = "${var.project_name}-db-subnet-group"
  }
}

# RDSインスタンス
resource "aws_db_instance" "main" {
  identifier = "${var.project_name}-db"

  engine         = "mysql"
  engine_version = "8.0"
  instance_class = var.db_instance_class

  allocated_storage     = 20
  max_allocated_storage = 100
  storage_type          = "gp2"

  db_name  = var.db_name
  username = var.db_username
  password = var.db_password

  db_subnet_group_name   = aws_db_subnet_group.main.name
  vpc_security_group_ids = [aws_security_group.rds.id]

  publicly_accessible = false
  skip_final_snapshot = true

  tags = {
    Name = "${var.project_name}-db"
  }
}

# =============================================================================
# ECR / CloudWatch Logs
# =============================================================================

# ECRリポジトリ
resource "aws_ecr_repository" "api" {
  name         = "${var.project_name}-api"
  force_delete = true

  tags = {
    Name = "${var.project_name}-api"
  }
}

# CloudWatch Logsグループ
resource "aws_cloudwatch_log_group" "api" {
  name              = "/ecs/${var.project_name}-api"
  retention_in_days = 7

  tags = {
    Name = "${var.project_name}-api-logs"
  }
}

コードを解説します。

Route53ホストゾーン

resource "aws_route53_zone" "main" {
  name = var.domain_name

カスタムドメインのDNSレコードを管理するためのホストゾーンを作成します。

nameは、ホストゾーンで管理するドメイン名を指定する設定です。ここではvar.domain_name(例: example.com)を指定し、このホストゾーンの中にALBやCloudFront向けのDNSレコードを追加していきます。

VPC

resource "aws_vpc" "main" {
  cidr_block           = var.vpc_cidr
  enable_dns_hostnames = true
  enable_dns_support   = true

VPCを作成します。

cidr_blockは、VPCのIPアドレス範囲を定義する設定です。10.0.0.0/16を指定することで、約65,000個のIPアドレスを確保しています。

enable_dns_hostnamesは、VPC内のリソースにDNSホスト名を自動的に付与するかどうかを制御する設定です。trueにすることで、EC2やRDSなどにDNSホスト名が割り当てられます。

enable_dns_supportは、VPC内でのDNS名前解決を有効にするかどうかを制御する設定です。trueにすることで、VPC内のリソースがドメイン名でお互いに通信できるようになります。

サブネット

resource "aws_subnet" "public" {
  count                   = length(var.availability_zones)
  cidr_block              = cidrsubnet(var.vpc_cidr, 8, count.index)
  map_public_ip_on_launch = true

パブリックサブネットを2つのアベイラビリティゾーンに作成します。

cidrsubnetは、VPCのCIDRブロックをもとにサブネット用のCIDRを自動計算する関数です。cidrsubnet(var.vpc_cidr, 8, count.index)とすることで、10.0.0.0/24と10.0.1.0/24が割り当てられます。

map_public_ip_on_launchは、サブネット内に起動したリソースにパブリックIPアドレスを自動付与するかどうかを制御する設定です。trueにすることで、ALBやNATゲートウェイがインターネットと通信できるようになります。

resource "aws_subnet" "private" {
  count      = length(var.availability_zones)
  cidr_block = cidrsubnet(var.vpc_cidr, 8, count.index + 10)

プライベートサブネットを2つのアベイラビリティゾーンに作成します。cidrsubnetの第3引数にcount.index + 10を指定することで、10.0.10.0/24と10.0.11.0/24が割り当てられ、パブリックサブネットとCIDRが重複しません。

NATゲートウェイ

resource "aws_nat_gateway" "main" {
  allocation_id = aws_eip.nat.id
  subnet_id     = aws_subnet.public[0].id
}

プライベートサブネットからインターネットにアクセスするためのNATゲートウェイを作成します。

allocation_idは、NATゲートウェイに割り当てるElastic IPを指定する設定です。Elastic IPを割り当てることで、固定のパブリックIPアドレスでインターネットにアクセスします。

subnet_idは、NATゲートウェイを配置するサブネットを指定する設定です。NATゲートウェイはパブリックサブネットに配置する必要があるため、aws_subnet.public[0]を指定しています。

💡 ポイント
このセクションではゾーナルNATゲートウェイを1つのAZにのみ配置しています。業務では、リージョン全体で1つのNATゲートウェイを共有できるリージョナルNATゲートウェイを使うと構成がシンプルになりますが、リージョン内のAZ数に応じた時間料金がかかります。ハンズオンではコストを抑えるため、ゾーナルNATゲートウェイを1つだけ配置するシングル構成にしています。
resource "aws_route_table" "private" {
  route {
    cidr_block     = "0.0.0.0/0"
    nat_gateway_id = aws_nat_gateway.main.id
  }

プライベートサブネット用のルートテーブルを作成します。

cidr_blockは、ルーティングの宛先となるIPアドレス範囲を指定する設定です。0.0.0.0/0を指定することで、すべてのインターネット宛トラフィックが対象になります。

nat_gateway_idは、トラフィックの転送先となるNATゲートウェイを指定する設定です。これにより、ECS FargateタスクがECRからイメージを取得したり、CloudWatch Logsにログを送信したりできるようになります。

セキュリティグループ(ALB用)

resource "aws_security_group" "alb" {
  ingress {
    from_port   = 443
    to_port     = 443
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }
  ingress {
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

ALB用のセキュリティグループを作成します。

ingressは、インバウンド(外部からの受信)トラフィックを許可するルールです。from_portとto_portは許可するポート範囲を指定する設定で、同じ値を指定すると単一ポートの許可になります。ここではHTTPS(443)とHTTP(80)の両方を許可しています。HTTPリクエストはALBのリスナーでHTTPSにリダイレクトされるため、ポート80も開放しておく必要があります。

RDS

resource "aws_db_instance" "main" {
  engine              = "mysql"
  engine_version      = "8.0"
  instance_class      = var.db_instance_class
  publicly_accessible = false
  skip_final_snapshot = true

MySQL 8.0のRDSインスタンスをプライベートサブネットに作成します。

publicly_accessibleは、RDSインスタンスにインターネットから直接アクセスできるかどうかを制御する設定です。falseにすることで、VPC内部からのみアクセスを許可し、セキュリティを確保しています。

skip_final_snapshotは、RDSインスタンスを削除する際にスナップショットを自動取得するかどうかを制御する設定です。trueにすることで、削除時のスナップショット取得をスキップし、ハンズオン終了時にスムーズに削除できるようにしています。本番環境ではfalseにして、削除前にスナップショットを取得してください。

ECRリポジトリ

resource "aws_ecr_repository" "api" {
  name         = "${var.project_name}-api"
  force_delete = true

APIのコンテナイメージを格納するECRリポジトリを作成します。

force_deleteは、リポジトリ内にイメージが残っている状態でも削除を許可するかどうかを制御する設定です。trueにすることで、terraform destroy時にイメージが残っていてもリポジトリを削除できます。

CloudWatch Logsグループ

resource "aws_cloudwatch_log_group" "api" {
  name              = "/ecs/${var.project_name}-api"
  retention_in_days = 7

ECSタスクのログを収集するCloudWatch Logsグループを作成します。

retention_in_daysは、ログの保持期間(日数)を制御する設定です。7にすることで、7日経過したログが自動的に削除されます。ハンズオン用のため短い保持期間にしていますが、本番環境では要件に応じて適切な期間を設定してください。

modules/base/outputs.tfに以下の内容を記述します。

output "vpc_id" {
  description = "VPC ID"
  value       = aws_vpc.main.id
}

output "public_subnet_ids" {
  description = "パブリックサブネットIDのリスト"
  value       = aws_subnet.public[*].id
}

output "private_subnet_ids" {
  description = "プライベートサブネットIDのリスト"
  value       = aws_subnet.private[*].id
}

output "alb_security_group_id" {
  description = "ALB用セキュリティグループID"
  value       = aws_security_group.alb.id
}

output "api_security_group_id" {
  description = "API用セキュリティグループID"
  value       = aws_security_group.api.id
}

output "rds_endpoint" {
  description = "RDSエンドポイント"
  value       = aws_db_instance.main.address
}

output "ecr_repository_url" {
  description = "ECRリポジトリURL"
  value       = aws_ecr_repository.api.repository_url
}

output "cloudwatch_log_group_name" {
  description = "CloudWatch Logsグループ名"
  value       = aws_cloudwatch_log_group.api.name
}

output "route53_zone_id" {
  description = "Route53ホストゾーンID"
  value       = aws_route53_zone.main.zone_id
}
📝 モジュールの出力について
モジュールのoutputs.tfで定義した値は、モジュールを呼び出す側でmodule.<モジュール名>.<出力名>として参照できます。これにより、モジュール間でリソースの情報を受け渡すことができます。

次に、environments/test/main.tfにbaseモジュールの呼び出しを追加します。localsブロックの下に以下を追記してください。

# 基盤モジュール(ネットワーク + RDS + ドメイン)
module "base" {
  source = "../../modules/base"

  project_name       = local.project_name
  vpc_cidr           = local.vpc_cidr
  availability_zones = local.availability_zones
  db_name            = local.db_name
  db_username        = local.db_username
  db_password        = var.db_password
  domain_name        = var.domain_name
}
📝 モジュール間の依存関係
baseモジュールの中でVPC、サブネット、セキュリティグループ、RDSをまとめて管理しているため、リソース間の依存関係はモジュール内部で自動的に解決されます。apiモジュールやfrontendモジュールは、baseモジュールの出力値を参照することで、必要なリソース情報を受け取ります。

2. Terraformの再初期化

baseモジュールを追加したため、Terraformを再初期化してモジュールを読み込みます。

terraform init

以下のように、baseモジュールの初期化が行われれば成功です。

Initializing modules...
- base in ../../modules/base

Initializing the backend...

Initializing provider plugins...

Terraform has been successfully initialized!
📝 terraform init が必要になるタイミング
本セクションに限らず、以下のタイミングで terraform init を実行する必要があります。既存リソースのコードを書き換えただけでは不要ですが、以下のいずれかに該当する場合は忘れずに実行してください。

- 新しいモジュールを追加したとき(本セクションのように module "base" { ... } を追加した場合)
- 既存モジュールの source を書き換えたとき(モジュールの配置先を変更した場合)
- 新しいプロバイダを追加したとき(例: provider "aws" { alias = "us_east_1" } を追加)
- バックエンド設定(backend.tf)を変更したとき
- Terraform本体のバージョンを変更したとき

逆に、モジュール内の main.tf / variables.tf / outputs.tf を編集しただけなら init は不要 です。その場合はそのまま terraform plan / terraform apply を実行できます。迷ったら init を実行しても害はないので、エラーが出たときは一度 init を試してみるのもおすすめです。

3. 差分の確認

terraform planで作成されるリソースを確認します。

terraform plan

以下のような実行結果が表示されます。

Terraform will perform the following actions:

  # module.base.aws_route53_zone.main will be created
  # module.base.aws_vpc.main will be created
  # module.base.aws_internet_gateway.main will be created
  # module.base.aws_subnet.public[0] will be created
  # module.base.aws_subnet.public[1] will be created
  # module.base.aws_subnet.private[0] will be created
  # module.base.aws_subnet.private[1] will be created
  # module.base.aws_route_table.public will be created
  # module.base.aws_route_table_association.public[0] will be created
  # module.base.aws_route_table_association.public[1] will be created
  # module.base.aws_eip.nat will be created
  # module.base.aws_nat_gateway.main will be created
  # module.base.aws_route_table.private will be created
  # module.base.aws_route_table_association.private[0] will be created
  # module.base.aws_route_table_association.private[1] will be created
  # module.base.aws_security_group.alb will be created
  # module.base.aws_security_group.api will be created
  # module.base.aws_security_group.rds will be created
  # module.base.aws_db_subnet_group.main will be created
  # module.base.aws_db_instance.main will be created
  # module.base.aws_ecr_repository.api will be created
  # module.base.aws_cloudwatch_log_group.api will be created

Plan: 22 to add, 0 to change, 0 to destroy.

Route53ホストゾーン、VPC、サブネット(パブリック2つ、プライベート2つ)、インターネットゲートウェイ、パブリックルートテーブル、ルートテーブルの関連付け(パブリック2つ)、Elastic IP、NATゲートウェイ、プライベートルートテーブル、ルートテーブルの関連付け(プライベート2つ)、セキュリティグループ(3つ)、DBサブネットグループ、RDSインスタンス、ECRリポジトリ、CloudWatch Logsグループの合計22リソースが作成されることを確認してください。

4. AWSへの反映

問題なければterraform applyで反映します。

terraform apply

確認プロンプトが表示されたら、yesと入力して実行します。以下のように、22件のリソースが作成されたことを確認します。

Apply complete! Resources: 22 added, 0 changed, 0 destroyed.
💡 ポイント
RDSの作成には 5〜15分程度 かかります。コマンドが止まっているように見えても、裏ではAWS側でデータベースインスタンスの起動処理が進んでいるので、焦らず待ちましょう。待ち時間を有効に使うために、以下のようなことをしておくのがおすすめです。

- ここまでに記述した environments/test/main.tf や modules/base/main.tf を読み返し、どのリソースがどんな順番で作られているかを追ってみる
- 前のセクションの📝ポイント(variables.tf と terraform.tfvars の役割分担、モジュール構成の理由など)を復習する
- AWSマネジメントコンソールで VPC や RDS のダッシュボードを開いておき、リソースが作成されていく様子を観察する
⚠️ ホストゾーンの作成でエラーが出る場合
「コンテンツ配信をしよう」のハンズオンで作成したRoute53ホストゾーンが残っている場合、同じドメイン名のホストゾーンが重複して作成されます。Terraformは正常に完了しますが、DNSの名前解決が正しく行われない可能性があります。Route53のダッシュボードで同じドメイン名のホストゾーンが2つ存在する場合は、古い方(Terraformで作成していない方)を手動で削除してください。

5. ネームサーバの設定

Terraformで新しいホストゾーンを作成すると、既存のホストゾーンとは異なるネームサーバ(NS)が割り当てられます。ドメインのDNS解決を新しいホストゾーンで行うために、ネームサーバの設定を更新する必要があります。

💡 ポイント
このネームサーバ設定は、本セクションで最もつまずきやすいポイントの一つです。設定が正しく行われていないと、この後のセクション(apiモジュール作成)で実行する terraform apply が、ACM証明書のDNS検証で 20〜30分ほど待機し続けた後にタイムアウト失敗 します。時間を無駄にしないためにも、次のセクションに進む前にネームサーバが正しく更新されていることを必ず確認してください。

Route53のダッシュボードでホストゾーンを開き、NSレコードに表示されている4つのネームサーバを確認します。

次に、Route53の「登録済みドメイン」を開き、対象のドメインを選択します。

「ネームサーバ」セクションで「編集」をクリックします。

ホストゾーンのNSレコードに表示されている4つのネームサーバに更新してください。NSレコードの値の末尾にはピリオド(.)が付いていますが、ネームサーバの設定時にはピリオドを除いた値を入力してください。

ネームサーバの設定が完了したら、次のステップに進みます。

💡 ポイント
お名前.comなどの外部レジストラでドメインを管理している場合は、Route53の「登録済みドメイン」ではなく、レジストラの管理画面でネームサーバを設定してください。手順はレジストラごとに異なるため、「<レジストラ名> ネームサーバ 変更」で検索するとスムーズです。

5.1 ネームサーバ設定のチェックリスト

次のセクションに進む前に、以下の4点が満たされていることを必ず確認してください。

  • ホストゾーンに表示されている4つのNSレコードをコピーした
  • ピリオド(.)を除いた値を設定した(例: ns-123.awsdns-45.com. → ns-123.awsdns-45.com)
  • レジストラ(Route53の「登録済みドメイン」または外部レジストラ)に4つすべて登録した
  • 自分のドメインを購入した方のレジストラ側で設定した(ホストゾーン側だけ見ても設定は完了しない)

5.2 ネームサーバ伝播の確認(推奨)

ネームサーバの設定変更はDNSへの反映に数分〜数十分かかることがあります。次のセクションに進んで terraform apply を実行する前に、以下のコマンドで実際の伝播状況を確認しておくと、ACM検証のタイムアウトを未然に防げます。

macOS / Linux:

dig NS <ご自身のドメイン名> +short

Windows(PowerShell):

Resolve-DnsName -Name <ご自身のドメイン名> -Type NS

以下のような実行結果が表示されます。

ns-123.awsdns-45.com.
ns-456.awsdns-78.net.
ns-789.awsdns-01.org.
ns-012.awsdns-23.co.uk.

Route53のホストゾーンに表示されているNSレコードと同じ4つが返ってくれば伝播完了です。異なるネームサーバが返ってくる場合は、設定が反映されるまで数分待ってから再度確認してください。

6. AWSコンソールでの確認

terraform applyの成功メッセージだけでは、リソースが意図した設定で作成されたかまではわかりません。AWSマネジメントコンソールで実際のリソースを確認し、設定値が正しいことを確かめます。

Route53: Route53のダッシュボードを開き、ご自身のドメイン名のホストゾーンが作成されていることを確認します。

  • NSレコードとSOAレコードが自動的に作成されていること

VPC: VPCのダッシュボードを開き、「test-noteapp-vpc」という名前のVPCが作成されていることを確認します。

  • IPv4 CIDR が「10.0.0.0/16」であること
  • DNSホスト名 が「有効」であること
  • DNS解決 が「有効」であること

サブネット: VPC > サブネット を開き、以下の4つのサブネットが作成されていることを確認します。

  • test-noteapp-public-1(ap-northeast-1a、パブリックIPの自動割り当て: はい)
  • test-noteapp-public-2(ap-northeast-1c、パブリックIPの自動割り当て: はい)
  • test-noteapp-private-1(ap-northeast-1a)
  • test-noteapp-private-2(ap-northeast-1c)

NATゲートウェイ: VPC > NATゲートウェイ を開き、「test-noteapp-nat-gw」が作成されていることを確認します。

  • 状態 が「Available」であること
  • サブネット がパブリックサブネット(test-noteapp-public-1)であること

セキュリティグループ: VPC > セキュリティグループ を開き、以下の3つのセキュリティグループが作成されていることを確認します。

  • test-noteapp-alb-sg(インバウンド: ポート443、ポート80)
  • test-noteapp-api-sg(インバウンド: ポート8000、ソースがALBのSG)
  • test-noteapp-rds-sg(インバウンド: ポート3306、ソースがAPIのSG)

RDS: RDSのダッシュボードを開き、「test-noteapp-db」という名前のRDSインスタンスが作成されていることを確認します。

  • エンジン が「MySQL 8.0」であること
  • インスタンスクラス が「db.t3.micro」であること

ECR: ECRのダッシュボードを開き、test-noteapp-apiリポジトリが作成されていることを確認します。

CloudWatch Logs: CloudWatch > ロググループ を開き、/ecs/test-noteapp-apiが作成されていることを確認します。

これらすべてのリソースがAWSコンソールで確認できれば、baseモジュールの作成は完了です。