frontendモジュールの作成

apiモジュールでAPIサーバの構築が完了したので、次にフロントエンドの配信基盤を構築します。S3バケットとCloudFrontディストリビューションを管理するモジュールを作成します。

このモジュールで作成されるリソースは以下のとおりです。

種類 リソース名 用途
ACM 証明書 example.com(us-east-1) CloudFrontのHTTPS通信用SSL証明書
S3 バケット test-noteapp-frontend-{アカウントID} フロントエンドの静的ファイルを格納
CloudFront ディストリビューション example.com 静的ファイルをCDNでグローバル配信
CloudFront OAC test-noteapp-oac S3へのアクセスをCloudFront経由に限定
Route53 Aレコード example.com → CloudFront ルートドメインをCloudFrontに紐付け
S3 オブジェクト index.html, style.css, script.js フロントエンドの静的ファイル

1. コードの記載

ここでは、フロントエンドの静的ファイルを配信するためのS3バケットと、CDNとしてグローバルにキャッシュ配信するCloudFrontディストリビューションを作成します。Terraformでは、resource "aws_s3_bucket"でS3バケットを、resource "aws_cloudfront_distribution"でCloudFrontを定義します。modules/frontend/ディレクトリの各ファイルにコードを記述していきます。

1.1 variables.tf

modules/frontend/variables.tfに以下の内容を記述します。

variable "project_name" {
  description = "プロジェクト名"
  type        = string
}

variable "front_source_dir" {
  description = "フロントエンドソースコードのディレクトリパス"
  type        = string
}

variable "domain_name" {
  description = "カスタムドメイン名"
  type        = string
}

variable "route53_zone_id" {
  description = "Route53ホストゾーンID"
  type        = string
}

コードを解説します。

project_name

variable "project_name" {
  type        = string
}

リソース名のプレフィックスとして使用します。S3バケット名やCloudFrontディストリビューションのタグに${var.project_name}-frontendの形式で付与されます。

front_source_dir

variable "front_source_dir" {
  type        = string
}

フロントエンドのソースコード(HTML/CSS/JS)があるディレクトリパスです。file関数やfilemd5関数でファイルを読み込み、S3にアップロードする際に使用します。

domain_name / route53_zone_id

variable "domain_name" {
  type        = string
}

variable "route53_zone_id" {
  type        = string
}

domain_nameはCloudFrontのカスタムドメイン(aliases)とACM証明書の発行に使用します。route53_zone_idはbaseモジュールから受け取り、ルートドメインをCloudFrontに向けるAレコードの作成に使用します。

1.2 main.tf

modules/frontend/main.tfに以下の内容を記述します。

terraform {
  required_providers {
    aws = {
      source                = "hashicorp/aws"
      configuration_aliases = [aws.us_east_1]
    }
  }
}

# CloudFront用ACM証明書(us-east-1で作成する必要がある)
resource "aws_acm_certificate" "frontend" {
  provider          = aws.us_east_1
  domain_name       = var.domain_name
  validation_method = "DNS"

  tags = {
    Name = "${var.project_name}-frontend-cert"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_route53_record" "frontend_cert_validation" {
  for_each = {
    for dvo in aws_acm_certificate.frontend.domain_validation_options : dvo.domain_name => {
      name   = dvo.resource_record_name
      record = dvo.resource_record_value
      type   = dvo.resource_record_type
    }
  }

  zone_id = var.route53_zone_id
  name    = each.value.name
  type    = each.value.type
  records = [each.value.record]
  ttl     = 60
}

resource "aws_acm_certificate_validation" "frontend" {
  provider                = aws.us_east_1
  certificate_arn         = aws_acm_certificate.frontend.arn
  validation_record_fqdns = [for record in aws_route53_record.frontend_cert_validation : record.fqdn]
}

data "aws_caller_identity" "current" {}

# フロントエンド用S3バケット
resource "aws_s3_bucket" "frontend" {
  bucket = "${var.project_name}-frontend-${data.aws_caller_identity.current.account_id}"

  tags = {
    Name = "${var.project_name}-frontend"
  }
}

# パブリックアクセスのブロック
resource "aws_s3_bucket_public_access_block" "frontend" {
  bucket = aws_s3_bucket.frontend.id

  block_public_acls       = true
  block_public_policy     = true
  ignore_public_acls      = true
  restrict_public_buckets = true
}

# Origin Access Control
resource "aws_cloudfront_origin_access_control" "frontend" {
  name                              = "${var.project_name}-frontend-oac"
  description                       = "OAC for frontend S3 bucket"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"
}

# CloudFrontディストリビューション
resource "aws_cloudfront_distribution" "frontend" {
  enabled             = true
  is_ipv6_enabled     = true
  default_root_object = "index.html"
  price_class         = "PriceClass_200"
  aliases             = [var.domain_name]

  origin {
    domain_name              = aws_s3_bucket.frontend.bucket_regional_domain_name
    origin_id                = "S3-${aws_s3_bucket.frontend.id}"
    origin_access_control_id = aws_cloudfront_origin_access_control.frontend.id
  }

  default_cache_behavior {
    allowed_methods        = ["GET", "HEAD", "OPTIONS"]
    cached_methods         = ["GET", "HEAD"]
    target_origin_id       = "S3-${aws_s3_bucket.frontend.id}"
    viewer_protocol_policy = "redirect-to-https"

    forwarded_values {
      query_string = false
      cookies {
        forward = "none"
      }
    }

    min_ttl     = 0
    default_ttl = 3600
    max_ttl     = 86400
  }

  # 存在しないパスへのアクセス時にindex.htmlを返す
  custom_error_response {
    error_code         = 403
    response_code      = 200
    response_page_path = "/index.html"
  }

  custom_error_response {
    error_code         = 404
    response_code      = 200
    response_page_path = "/index.html"
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  viewer_certificate {
    acm_certificate_arn      = aws_acm_certificate_validation.frontend.certificate_arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }

  tags = {
    Name = "${var.project_name}-frontend"
  }
}

# Route53レコード(example.com → CloudFront)
resource "aws_route53_record" "frontend" {
  zone_id = var.route53_zone_id
  name    = var.domain_name
  type    = "A"

  alias {
    name                   = aws_cloudfront_distribution.frontend.domain_name
    zone_id                = aws_cloudfront_distribution.frontend.hosted_zone_id
    evaluate_target_health = false
  }
}

# CloudFrontからのアクセス用バケットポリシー
resource "aws_s3_bucket_policy" "frontend" {
  bucket = aws_s3_bucket.frontend.id
  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Sid    = "AllowCloudFrontServicePrincipal"
        Effect = "Allow"
        Principal = {
          Service = "cloudfront.amazonaws.com"
        }
        Action   = "s3:GetObject"
        Resource = "${aws_s3_bucket.frontend.arn}/*"
        Condition = {
          StringEquals = {
            "AWS:SourceArn" = aws_cloudfront_distribution.frontend.arn
          }
        }
      }
    ]
  })
}

# index.htmlをS3にアップロード
resource "aws_s3_object" "index_html" {
  bucket       = aws_s3_bucket.frontend.id
  key          = "index.html"
  source       = "${var.front_source_dir}/index.html"
  content_type = "text/html"
  etag         = filemd5("${var.front_source_dir}/index.html")
}

# style.cssをS3にアップロード
resource "aws_s3_object" "style_css" {
  bucket       = aws_s3_bucket.frontend.id
  key          = "style.css"
  source       = "${var.front_source_dir}/style.css"
  content_type = "text/css"
  etag         = filemd5("${var.front_source_dir}/style.css")
}

# script.jsをS3にアップロード(API_URLをカスタムドメインに差し替え)
resource "aws_s3_object" "script_js" {
  bucket       = aws_s3_bucket.frontend.id
  key          = "script.js"
  content      = replace(
    file("${var.front_source_dir}/script.js"),
    "http://localhost:8000",
    "https://api.${var.domain_name}"
  )
  content_type = "application/javascript"
}

コードを解説します。

ACM証明書(us-east-1)

resource "aws_acm_certificate" "frontend" {
  provider          = aws.us_east_1
  domain_name       = var.domain_name
  validation_method = "DNS"

CloudFront用のSSL証明書を作成します。CloudFrontで使用するACM証明書はus-east-1(バージニア北部)リージョンで作成する必要があるため、provider = aws.us_east_1を指定しています。baseモジュールのALB用証明書(東京リージョン)とは別に作成します。

S3バケットとパブリックアクセスブロック

resource "aws_s3_bucket" "frontend" {
  bucket = "${var.project_name}-frontend-${data.aws_caller_identity.current.account_id}"

フロントエンドの静的ファイル(HTML/CSS/JS)を保存するS3バケットです。バケット名にアカウントIDを含めてグローバルで一意にしています。

resource "aws_s3_bucket_public_access_block" "frontend" {
  block_public_acls       = true
  block_public_policy     = true
  ignore_public_acls      = true
  restrict_public_buckets = true

S3バケットへの直接アクセスを完全にブロックします。すべての設定をtrueにすることで、パブリックACLやパブリックバケットポリシーが適用されないようにしています。ユーザはCloudFront経由でのみファイルにアクセスできます。

CloudFrontディストリビューション

resource "aws_cloudfront_distribution" "frontend" {
  enabled             = true
  default_root_object = "index.html"
  price_class         = "PriceClass_200"
  aliases             = [var.domain_name]

  viewer_certificate {
    acm_certificate_arn      = aws_acm_certificate_validation.frontend.certificate_arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }

S3バケットのコンテンツをCDNで配信するCloudFrontディストリビューションです。

default_root_objectは、ルートURL(例: https://example.com/)にアクセスした際に返すファイルを指定する設定です。index.htmlを指定することで、ルートアクセス時にトップページが表示されます。

aliasesは、CloudFrontに関連付けるカスタムドメインを指定する設定です。ここではvar.domain_name(例: example.com)を指定しています。

viewer_protocol_policyは、ユーザがHTTPでアクセスした際の動作を制御する設定です。redirect-to-httpsにすることで、HTTPアクセスが自動的にHTTPSにリダイレクトされます。

viewer_certificateでus-east-1のACM証明書を設定してHTTPS通信を有効にし、price_classをPriceClass_200にすることでアジア・北米・欧州のエッジロケーションを使用します。

OAC(Origin Access Control)

resource "aws_cloudfront_origin_access_control" "frontend" {
  name                              = "${var.project_name}-frontend-oac"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"

S3へのアクセスをCloudFront経由に限定するためのOAC(Origin Access Control)です。

signing_protocolは、CloudFrontがS3にリクエストする際の署名プロトコルを指定する設定です。sigv4を指定することで、AWS Signature Version 4による署名が使用されます。

signing_behaviorは、CloudFrontがS3へのリクエストに署名を付与するタイミングを制御する設定です。alwaysにすることで、すべてのリクエストに署名が付与され、S3バケットのパブリックアクセスをブロックしたままCloudFrontからのみコンテンツを取得できます。

S3バケットポリシー

resource "aws_s3_bucket_policy" "frontend" {
  policy = jsonencode({
    Statement = [{
      Principal = { Service = "cloudfront.amazonaws.com" }
      Action    = "s3:GetObject"
      Resource  = "${aws_s3_bucket.frontend.arn}/*"
      Condition = {
        StringEquals = {
          "AWS:SourceArn" = aws_cloudfront_distribution.frontend.arn
        }
      }
    }]
  })

CloudFrontからのみS3オブジェクトのGetObjectを許可するバケットポリシーです。Conditionで特定のCloudFrontディストリビューションのARNを指定することで、他のCloudFrontディストリビューションや直接アクセスからの読み取りを防止しています。

S3オブジェクト(HTML/CSS/JS)

resource "aws_s3_object" "script_js" {
  bucket       = aws_s3_bucket.frontend.id
  key          = "script.js"
  content      = replace(
    file("${var.front_source_dir}/script.js"),
    "http://localhost:8000",
    "https://api.${var.domain_name}"
  )
  content_type = "application/javascript"
}

フロントエンドの静的ファイルをS3にアップロードします。

content_typeは、ファイルのMIMEタイプを指定する設定です。ブラウザがファイルを正しく解釈するために、text/html、text/css、application/javascriptなどを指定します。

etagは、ファイルの変更を検知するためのハッシュ値を指定する設定です。filemd5関数でファイルのMD5ハッシュを計算し、ファイル内容が変わった場合のみS3にアップロードし直します。

script.jsではreplace関数を使用しています。replaceは文字列内の特定の部分を別の文字列に置き換える関数で、ここではhttp://localhost:8000をhttps://api.<ドメイン名>に動的に差し替えています。これにより、ソースコードを手動で修正することなく、デプロイ先のAPI URLが自動的に設定されます。

Route53 Aレコード

resource "aws_route53_record" "frontend" {
  zone_id = var.route53_zone_id
  name    = var.domain_name
  type    = "A"

  alias {
    name                   = aws_cloudfront_distribution.frontend.domain_name
    zone_id                = aws_cloudfront_distribution.frontend.hosted_zone_id

ルートドメイン(例: example.com)をCloudFrontディストリビューションに向けるエイリアスレコードです。これにより、ユーザはhttps://example.comでフロントエンドにアクセスできるようになります。

1.3 outputs.tf

modules/frontend/outputs.tfに以下の内容を記述します。

output "cloudfront_domain_name" {
  description = "CloudFrontドメイン名"
  value       = aws_cloudfront_distribution.frontend.domain_name
}

output "cloudfront_distribution_id" {
  description = "CloudFrontディストリビューションID"
  value       = aws_cloudfront_distribution.frontend.id
}

次に、environments/test/main.tfを更新します。frontendモジュールではCloudFront用のACM証明書をus-east-1で作成する必要があるため、まずalias付きの2つ目のプロバイダを追加します。localsブロックの下に以下を追記してください。

provider "aws" {
  alias  = "us_east_1"
  region = "us-east-1"
}

CloudFront用のACM証明書はus-east-1(バージニア北部)リージョンで作成する必要があるため、alias付きのプロバイダを定義しています。このプロバイダは、frontendモジュール内でprovider = aws.us_east_1として使用されます。

📝 エイリアスプロバイダとは
Terraformでは通常、provider "aws" { region = "ap-northeast-1" } のように1つのリージョンに対して1つのプロバイダを定義します。しかし、複数のリージョンを同時に扱いたい場合(例: メインは東京リージョン、CloudFront用ACMはバージニア北部)は、alias を付けた2つ目のプロバイダを定義します。エイリアスプロバイダはデフォルトでは使われず、リソースやモジュールで明示的に provider = aws.us_east_1 のように指定したときだけ使われます。モジュールに渡す場合は、後ほど記述する module "frontend" { providers = { aws.us_east_1 = aws.us_east_1 } } のように providers 引数で受け渡す必要があります。マルチリージョン構成では定番のパターンなので、覚えておくと今後の応用でも役立ちます。

続けて、frontendモジュールの呼び出しを追加します。追加したプロバイダ設定の下に以下を追記してください。

# フロントエンドモジュール(S3 + CloudFront)
module "frontend" {
  source = "../../modules/frontend"

  providers = {
    aws           = aws
    aws.us_east_1 = aws.us_east_1
  }

  project_name     = local.project_name
  front_source_dir = "${path.module}/../../app/api/front"
  domain_name      = var.domain_name
  route53_zone_id  = module.base.route53_zone_id
}
📝 path.module とは
path.module はTerraformの組み込み変数で、今コードが書かれているモジュールのディレクトリ(ファイルシステム上のパス) を返します。ここでは environments/test/main.tf に書かれているので、path.module は environments/test/ を指します。${path.module}/../../app/api/front と書くことで、environments/test/ を起点に「2つ上のディレクトリ配下の app/api/front」という意味になり、プロジェクトルートの app/api/front/ ディレクトリを指します。カレントディレクトリに依存しない安全なパス指定方法なので、ファイルや資産を参照する場面では path.module を使うのが定番です。

2. Terraformの再初期化

frontendモジュールを追加したため、Terraformを再初期化します。environments/test/ディレクトリにいることを確認してから実行してください。

terraform init

3. 差分の確認

terraform planで差分を確認します。

terraform plan

以下のような実行結果が表示されます。

Terraform will perform the following actions:

  # module.frontend.aws_acm_certificate.frontend will be created
  # module.frontend.aws_acm_certificate_validation.frontend will be created
  # module.frontend.aws_route53_record.frontend will be created
  # module.frontend.aws_route53_record.frontend_cert_validation["example.com"] will be created
  # module.frontend.aws_cloudfront_distribution.frontend will be created
  # module.frontend.aws_cloudfront_origin_access_control.frontend will be created
  # module.frontend.aws_s3_bucket.frontend will be created
  # module.frontend.aws_s3_bucket_policy.frontend will be created
  # module.frontend.aws_s3_bucket_public_access_block.frontend will be created
  # module.frontend.aws_s3_object.index_html will be created
  # module.frontend.aws_s3_object.style_css will be created
  # module.frontend.aws_s3_object.script_js will be created

Plan: 12 to add, 0 to change, 0 to destroy.

ACM証明書(us-east-1)、DNS検証レコード、証明書検証、Route53 Aレコード(CloudFront用)、S3バケット、パブリックアクセスブロック、OAC(Origin Access Control)、CloudFrontディストリビューション、バケットポリシー、S3オブジェクト(3ファイル)の合計12リソースが作成されることを確認してください。

4. AWSへの反映

問題なければterraform applyで反映します。

terraform apply

確認プロンプトが表示されたら、yesと入力して実行します。以下のように、12件のリソースが作成されたことを確認します。

Apply complete! Resources: 12 added, 0 changed, 0 destroyed.
💡 ポイント
CloudFrontディストリビューションの作成には数分かかる場合があります。terraform applyが完了するまでしばらくお待ちください。

5. AWSコンソールでの確認

AWSマネジメントコンソールで以下の内容を確認してください。

ACM(Certificate Manager): ACMのダッシュボードを開きます。CloudFront用のACM証明書はus-east-1で作成されるため、リージョンを**バージニア北部(us-east-1)**に切り替えてから確認してください。

  • <ドメイン名> の証明書が作成されていること
  • ステータス が「発行済み」であること

Route53: Route53のダッシュボードでホストゾーンを開き、以下のレコードが追加されていることを確認します。

  • <ドメイン名> のAレコード(CloudFrontへのエイリアス)
  • ACM証明書のDNS検証用のCNAMEレコード

S3: S3のダッシュボードを開き、test-noteapp-frontend-<アカウントID>バケットが作成されていることを確認します。

script.jsを開き「開く」をクリックします。

  • const API_URLのところがhttps://<ドメイン名>となっていること

CloudFront: CloudFrontのダッシュボードを開き、ディストリビューションが作成されていることを確認します。

  • ステータス が「有効」であること
  • オリジン がS3バケットであること
  • デフォルトルートオブジェクト が「index.html」であること

これらすべてのリソースがAWSコンソールで確認できれば、frontendモジュールのデプロイは完了です。

6. フロントエンドの動作確認

フロントエンドの静的ファイルは、terraform applyの実行時にS3に自動的にアップロードされています。script.js内のAPI_URLも、Terraformのreplace関数によりhttps://api.<ドメイン名>に自動で差し替えられています。

カスタムドメインを設定したので、ブラウザで https://<ドメイン名> にアクセスしてください。

「ノートアプリケーション」の画面が表示され、apiモジュールの動作確認で作成した「Test Note」が「ノート一覧」に表示されていれば成功です。

画面からノートの作成・編集・削除ができることも確認してください。

⚠️ 画面が表示されない場合
CloudFrontのデプロイには数分かかる場合があります。しばらく待ってからリトライしてください。
⚠️ ノート一覧が表示されない場合
ブラウザの開発者ツール(F12)でコンソールタブを開き、APIへの接続エラーが出ていないか確認してください。script.js内のAPI_URLがhttps://api.<ドメイン名>に正しく差し替えられているかは、S3バケット内のscript.jsをダウンロードして確認できます。CloudFrontのキャッシュが古い場合は、以下のコマンドでキャッシュを無効化してください。ディストリビューションIDはAWSコンソールの「CloudFront > ディストリビューション」から確認できます。
aws cloudfront create-invalidation --distribution-id <CloudFrontのディストリビューションID> --paths "/*"

フロントエンドからAPIを経由してデータの操作ができることを確認できれば、すべてのモジュールの構築と動作確認は完了です。