data source による既存リソースの参照

既存の AWS リソースを Terraform のコードから「参照だけ」したい場面があります。手動で作成した VPC の ID を使って別のリソースを立てたい、AWS が公式提供する最新 Amazon Linux の AMI ID を取得したい、といった要望です。data ブロックを使うと、Terraform の外にある値を読み取り専用で取り込んで、他のリソース定義に差し込めるようになります。

1. 概要

1.1 Data Sources とは

これまで resource ブロックを使って、新しくAWSリソースを作成・管理してきました。 しかし、実際には 「すでに存在するリソースの情報を使いたい」 という場面が多々あります。

  • 「管理コンソールで手動作成したVPCの中に、Terraformでサーバを立てたい」
  • 「AWSが提供している最新のAmazon LinuxのAMI IDを知りたい」

このように、Terraformの外にある情報や、既存のリソース情報を 「参照」(Read Only) するために使うのが data ブロックです。

💡 ポイント
data(参照のみ)と import(管理下に取り込む)の違いに注意してください。data はリソースを「見るだけ」で、terraform destroy しても削除されません。一方、import は既存リソースをTerraformの管理下に置くため、terraform destroy で削除対象になります。

2. 記載方法

resource とよく似ていますが、先頭が data になります。 検索条件(フィルター)を指定して、対象のリソースを特定します。

data "リソース型" "名前" {
  # 検索条件などを記載
  filter {
    name   = "条件の項目名"
    values = ["探したい値"]
  }
}

参照する際は、resource の時と同様に、以下のように記述します。

data.リソース型.名前.属性

3. サンプルコード

data の最も便利な使い方のひとつが、「最新のAMI IDの取得」です。 通常、EC2のAMI ID(ami-0abcdef...)は不定期に変更されるため、コードに直接書くと古くなってしまいます。data を使うことで、常に最新のIDを自動で取得できます。

以下の例では、name が "al2023-ami-2023.*-x86_64" となっているものを data として取り込みます。

data "aws_ami" "latest_al2023" {
  most_recent = true
  owners      = ["amazon"]

  filter {
    name   = "name"
    values = ["al2023-ami-2023.*-x86_64"]
  }
}

取り込んだ内容を、EC2インスタンス作成時のAMIで使用することができます。

resource "aws_instance" "web" {
  # dataからIDを参照する
  ami           = data.aws_ami.latest_al2023.id
  instance_type = "t2.micro"
}

4. data ブロックの動作確認

今回は、すでに作成済みのVPCを data によりTerraformに取り込み、その属性を利用するハンズオンを実施します。

4.1 検証用VPCの作成

まず、data で取り込むためのVPCを作成します。

VPCのダッシュボードを開き、左側のメニューからお使いのVPCを選択した上で、VPCを作成をクリックします。

名前タグに test-vpc、IPv4 CIDRに 10.0.0.0/16 を入力し、VPCを作成をクリックします。

無事に test-vpc が作成されたら、VPC-IDを控えておきます。

4.2 コードの記載

コードを記載します。main.tf を以下の内容に書き換えてください。

vpc-xxxxxxxxxxxxxxxxx の部分は、先ほど控えたVPC IDに置き換えてください。

provider "aws" {
  region = "ap-northeast-1"
}

# -----------------------------------------------------------
# 1. 既存のVPCを取り込む (Data Source)
# -----------------------------------------------------------
data "aws_vpc" "selected" {
  # ★ここに手動で作ったVPCのIDを記述してください
  id = "vpc-xxxxxxxxxxxxxxxxx"
}

# -----------------------------------------------------------
# 2. そのVPCの中にサブネットを作成 (Resource)
# -----------------------------------------------------------
resource "aws_subnet" "private" {
  # data経由でVPC IDを参照
  vpc_id = data.aws_vpc.selected.id

  # ★VPCのCIDR範囲内で、かつ重複しない値を指定してください
  cidr_block = "10.0.1.0/24"

  # 任意: Availability Zoneの指定
  availability_zone = "ap-northeast-1a"

  tags = {
    Name = "my-terraform-subnet"
  }
}

このコードは、data ブロックでVPCを取り込み、そのIDを新しく作るサブネットとして指定しています。

4.3 リソースの作成

以下のコマンドで、Terraform がインストールされていることを確認します。

terraform --version

以下のように Terraform のバージョンが表示されれば、インストールは確認できています。

Terraform vX.X.X
on darwin_arm64

バージョンが表示されない場合は、Terraformのインストール を先に実施してください。

インストールが確認できたら、apply コマンドで、実際にリソースを作成します。

terraform apply
⚠️ 「InvalidVpcID.NotFound」エラーが出る場合
指定したVPC IDが見つかりません。
AWSコンソールでVPCの一覧を確認し、正しいVPC IDをコードに記載してください。VPC IDはvpc-で始まる文字列です。
⚠️ 「InvalidSubnet.Conflict」エラーが出る場合
指定したCIDRブロック(10.0.1.0/24)が既存のサブネットと重複しています。
別のCIDR(例:10.0.2.0/24や10.0.10.0/24)に変更してください。

terraform apply の plan 部分を見ると、VPCは特に変更されず、新しいサブネットの作成のみが変更として検知されます。

data.aws_vpc.selected: Reading...
data.aws_vpc.selected: Read complete after 0s [id=vpc-0e594e9849ae57c4b]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the following symbols:
  + create

Terraform will perform the following actions:

  # aws_subnet.private will be created
  + resource "aws_subnet" "private" {
      + arn                                            = (known after apply)
      + assign_ipv6_address_on_creation                = false
      + availability_zone                              = "ap-northeast-1a"
      + availability_zone_id                           = (known after apply)
      + cidr_block                                     = "10.0.1.0/24"
      + enable_dns64                                   = false
      + enable_resource_name_dns_a_record_on_launch    = false
      + enable_resource_name_dns_aaaa_record_on_launch = false
      + id                                             = (known after apply)
      + ipv6_cidr_block_association_id                 = (known after apply)
      + ipv6_native                                    = false
      + map_public_ip_on_launch                        = false
      + owner_id                                       = (known after apply)
      + private_dns_hostname_type_on_launch            = (known after apply)
      + region                                         = "ap-northeast-1"
      + tags                                           = {
          + "Name" = "my-terraform-subnet"
        }
      + tags_all                                       = {
          + "Name" = "my-terraform-subnet"
        }
      + vpc_id                                         = "vpc-0e594e9849ae57c4b"
    }

Plan: 1 to add, 0 to change, 0 to destroy.

このように、VPCは特に変化せず、サブネットのみが作成される形となります。

実際に作成されるサブネットを見ると、VPCの部分に無事に test-vpc のIDが設定されていればOKです。

4.4 リソースの削除

確認が終わったら削除しておきます。

terraform destroy

ここでポイントとなるのは、data ブロックは「参照しているだけ」なので、destroy してもVPC自体が消えることはありません。あくまで作成したサブネットだけが消えます。

data.aws_vpc.selected: Reading...
data.aws_vpc.selected: Read complete after 1s [id=vpc-0e594e9849ae57c4b]
aws_subnet.private: Refreshing state... [id=subnet-0e93b71d216abffb6]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the following symbols:
  - destroy

Terraform will perform the following actions:

  # aws_subnet.private will be destroyed
  - resource "aws_subnet" "private" {
      - arn                                            = "arn:aws:ec2:ap-northeast-1:125605020607:subnet/subnet-0e93b71d216abffb6" -> null
      - assign_ipv6_address_on_creation                = false -> null
      - availability_zone                              = "ap-northeast-1a" -> null
      - availability_zone_id                           = "apne1-az4" -> null
      - cidr_block                                     = "10.0.1.0/24" -> null
      - enable_dns64                                   = false -> null
      - enable_lni_at_device_index                     = 0 -> null
      - enable_resource_name_dns_a_record_on_launch    = false -> null
      - enable_resource_name_dns_aaaa_record_on_launch = false -> null
      - id                                             = "subnet-0e93b71d216abffb6" -> null
      - ipv6_native                                    = false -> null
      - map_customer_owned_ip_on_launch                = false -> null
      - map_public_ip_on_launch                        = false -> null
      - owner_id                                       = "125605020607" -> null
      - private_dns_hostname_type_on_launch            = "ip-name" -> null
      - region                                         = "ap-northeast-1" -> null
      - tags                                           = {
          - "Name" = "my-terraform-subnet"
        } -> null
      - tags_all                                       = {
          - "Name" = "my-terraform-subnet"
        } -> null
      - vpc_id                                         = "vpc-0e594e9849ae57c4b" -> null
        # (4 unchanged attributes hidden)
    }

Plan: 0 to add, 0 to change, 1 to destroy.

Do you really want to destroy all resources?
  Terraform will destroy all your managed infrastructure, as shown above.
  There is no undo. Only 'yes' will be accepted to confirm.

  Enter a value: yes

aws_subnet.private: Destroying... [id=subnet-0e93b71d216abffb6]
aws_subnet.private: Destruction complete after 1s

Destroy complete! Resources: 1 destroyed.
$