S3リモートバックエンドへの移行

まず、Terraformのステート(状態管理ファイル)を保存するためのS3バケットを作成し、そこへローカルのステートを移行します。

1. バックエンド用S3の作成

まずはローカルで state ファイルを管理しながら、リモートバックエンドでの保存先となるS3バケットをTerraformで作成します。

💡 ポイント
ここでのS3バケットの作成は、AWSマネジメントコンソールではなく、Terraformのterraform applyで行います。コンソールで手動作成してしまうと、terraform applyの実行時に「BucketAlreadyOwnedByYou」エラーが発生します。もし手動で作成してしまった場合は、コンソールからバケットを削除してからterraform applyを実行してください。

main.tf に以下を記述してください。

provider "aws" {
  region = "ap-northeast-1"
}

# 1. バケット本体
resource "aws_s3_bucket" "tf_state" {
  bucket = "tf-course-state-bucket-unique-name" # ご自身のバケット名にしてください
}

# 2. バージョニング設定
resource "aws_s3_bucket_versioning" "versioning" {
  bucket = aws_s3_bucket.tf_state.id
  versioning_configuration {
    status = "Enabled"
  }
}

このファイルでは、保存先となるS3を作成し、さらにバージョニングを有効にする設定を行っています。state ファイルは誤って削除されたり、不正に更新されると今までの履歴がわからなくなってしまったり、不正なリソース操作が行われる恐れがあるため、バージョニング管理をしておくことが推奨されます。

バージョニングについては、Retaining multiple versions of objects with S3 Versioning(AWS公式ドキュメント)に「Versioning-enabled buckets can help you recover objects from accidental deletion or overwrite.」と明記されており、誤削除・誤上書きからの復旧手段としてバージョニングが有効であることが読み取れます(原文は英語表示時のもので、日本語表示への切り替えは画面右上の言語セレクタから行えます)。

2. リソースの作成

以下のコマンドで、Terraform がインストールされていることを確認します。

terraform --version

以下のように Terraform のバージョンが表示されれば、インストールは確認できています。

Terraform vX.X.X
on darwin_arm64

バージョンが表示されない場合は、Terraformのインストール を先に実施してください。

インストールが確認できたら、apply コマンドを実行し、S3バケットを作成します。

terraform apply

この時点では、Terraformの状態ファイル(terraform.tfstate)はまだパソコンの中(ローカル)にあります。

3. バックエンド設定の追加

次に、Terraformの state ファイルの保存先を、先ほど作成したS3バケットに向ける設定を行います。

main.tf に、terraform ブロックを追加します。

provider "aws" {
  region = "ap-northeast-1"
}

terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "~> 6.0"
    }
  }

  backend "s3" {
    bucket       = "tf-course-state-bucket-unique-name" # 作成したバケット名
    key          = "dev/terraform.tfstate"
    region       = "ap-northeast-1"

    # DynamoDBを使わずにS3だけでロック管理
    use_lockfile = true
  }
}

# 1. バケット本体
resource "aws_s3_bucket" "tf_state" {
  bucket = "tf-course-state-bucket-unique-name" # ご自身のバケット名にしてください
}

# 2. バージョニング設定
resource "aws_s3_bucket_versioning" "versioning" {
  bucket = aws_s3_bucket.tf_state.id
  versioning_configuration {
    status = "Enabled"
  }
}

4. 移行の実行(ローカル → S3)

この後初期化を行うと、設定変更を適用し、実際にステートファイルをS3へアップロードします。

terraform init

実行中に以下のような確認メッセージが表示されます。

「ローカルにある tfstate を、新しく設定されたS3バックエンドにコピーしますか?」という意味です。

Do you want to copy existing state to the new backend?
...
Enter a value:

ここで yes と入力してEnterキーを押します。

Terraform has been successfully initialized! と表示されれば完了です。

これにより、手元の terraform.tfstate の内容がS3バケット内の dev/terraform.tfstate に移行されました。

念の為、作成したS3バケットを開き、dev フォルダをひらくと、terraform.tfstate ファイルが作成されていることを確認できます。

5. リソースの削除

terraform destroy を実行すると、バケット内にステートファイルが残っているため BucketNotEmpty(バケットが空ではない)というエラーが発生し、削除に失敗します。

これを解決するには、main.tf のS3リソース定義に force_destroy = true を追加します。これによって、Terraformが自動的にバケットの中身を空にしてからバケット自体を削除してくれるようになります。

resource "aws_s3_bucket" "tf_state" {
  bucket        = "tf-course-state-bucket-unique-name"
  force_destroy = true  # この行を追加
}

修正後、以下の手順で削除します。

  1. terraform apply (force_destroy の設定を一度反映させる)
  2. terraform destroy (削除実行)

※注意: 自身のステートファイルを保存しているバケットを自身で削除するため、コマンドの最後の最後で「ステートの更新に失敗しました(バケットがないため)」という旨のエラーが出ることがありますが、リソース自体は正常に削除されます。

💡 ポイント
実際には、バックエンド用のリソース(S3バケット・DynamoDBテーブル)とアプリケーション用のリソースを別のTerraform構成(ディレクトリ)で管理するのが一般的です。こうすることで、アプリケーション側で terraform destroy を実行してもバックエンドのリソースが巻き込まれる心配がなくなります。