Variables

variables について解説します。

1. 記載方法

locals がコード内で計算や再利用をするための「ローカル変数」であるのに対し、variables は外部から値を注入するための「入力変数」です。環境(開発、本番など)ごとに異なる値を設定したい場合などによく利用されます。

1.1 基本的な記載方法

まずは最もシンプルな定義方法です。variable ブロックに変数名を記述します。

variable "stage" {}

このように中身を空にして定義した場合、terraform apply などの実行時に「この変数の値は何ですか?」と対話形式で入力を求められます。

variables では、変数の役割や型を明確にするために、以下の属性を付与することが一般的です。

1.2 説明(description)

description は変数の説明を記載します。チーム開発などで、何のための変数かを伝えるのに役立ちます。

variable "stage" {
  description = "環境名(例: dev, test, prod)"
}

1.3 変数の型(type)

type は、 変数の型(string、number、bool、list など)を指定します。意図しないデータが入るのを防ぎます。

例えば、下記は文字列を表す string を指定した場合です。この場合、"" で囲んだ「文字列」を指定できます。

variable "stage" {
  type        = string
}

type に number を指定した場合、1や2などの数値のみが指定できます。

variable "stage" {
  type        = number
}

type に bool を指定した場合は、true または false の真偽で値を表します。

variable "stage" {
  type        = bool
}

最後に、type に list を指定すると、["開発", "テスト", "本番"] のように、複数の値を結合して利用できます。list(string)、list(number) のように、list の中にさらに型を指定します。

variable "stage" {
  type        = list(string)
}

1.4 初期値(default)

default は変数の初期値を設定します。これを設定すると、実行時に入力を求められなくなります。

variable "stage" {
  default     = "test"
}

定義した変数は、var.変数名 という形で利用します。 以前のVPCの例で、locals の代わりに variables を使ってみましょう。

💡 ポイント
「variables だけで全部できるのでは?」と思われるかもしれません。確かに技術的には variables で全てをカバーすることも可能です。しかし、ファイル内部で完結する定義(プレフィックスや計算結果など)まで variables にしてしまうと、外部から渡す必要のない値まで外部に露出してしまい、コードが冗長になります。

使い分けの基準は外部から値を変えたいかどうかです。
- variables:環境(開発/本番)ごとに変えたい値や、外部から渡したい値に使う
- locals:そのファイル内で完結する固定値や計算結果に使い、コードを簡潔に保つ
resource "aws_vpc" "vpc" {
  cidr_block = "10.0.0.0/16"
  tags = {
    Name = "${var.stage}-vpc"
  }
}

1.5 ファイルでの初期値定義

また、専用のファイル(terraform.tfvars)で外から指定することも可能です。 これにより、コード自体(main.tf)を書き換えずに、設定値だけを切り替えることができます。

stage = "prod"
📝 terraform.tfvars の役割
terraform.tfvars は、環境ごとやユーザごとに切り替えたい値をまとめて定義するための専用ファイルです。パスワードなどの機密情報だけでなく、環境名、CIDRブロック、ドメイン名など、環境やユーザによって異なる値全般をここに集約します。terraform.tfvars で値を指定できるのは variables.tf に宣言されている変数だけ で、宣言されていない名前を書いてもエラーになります。つまり、variables.tf が「受け取れる変数の一覧(宣言)」、terraform.tfvars が「実際に渡す値(代入)」という役割分担になっています。

2. 動作確認

それでは、実際にコードを書いて挙動を確認してみましょう。

2.1 標準的な使い方

まず、main.tf に以下のようなコードを記載します。

provider "aws" {
  region = "ap-northeast-1"
}

# default値なしで定義
variable "stage" {
  description = "環境名"
  type        = string
}

resource "aws_vpc" "vpc" {
  cidr_block = "10.0.0.0/16"
  tags = {
    Name = "${var.stage}-vpc"
  }
}

このコードでは、variables として stage を定義しています。description として「環境名」という説明、type として文字列を表す string を指定しています。default の値は特に指定していません。

この状態で terraform apply を実行してみます。

terraform apply

そうすると、Enter a value という文言により、var.stage の値を入力するように促されます。

$ terraform apply
var.stage
  環境名

  Enter a value:

ここで、今回は開発環境を表す develop を入力してみましょう。

すると、develop-vpc という名前でVPCが作成されます。

⚠️ 変数に日本語を入力するとエラーになる場合
変数の値は半角英数字とハイフン(-)やアンダースコア(_)のみを使用することを推奨します。

2.2 defaultの指定

default を指定した場合の挙動を確認します。下記のように、default として "test" という文言を指定してみます。

variable "stage" {
  description = "環境名"
  type        = string
  default     = "test"
}

この状態で、terraform apply を実行します。

terraform apply

すると、VPCの名前が test-vpc として作成されます。

2.3 外部ファイルから値の指定

最後に、外部ファイルから値を上書きしてみます。 同じディレクトリに terraform.tfvars というファイルを作成します。Visual Studio Codeのエクスプローラーで作業フォルダを右クリックし、「新しいファイル」を選択してterraform.tfvarsという名前で作成してください。

terraform-basic-handson
├── main.tf
└── terraform.tfvars  ← このファイルを作成

作成したファイルに以下の内容を記述して保存します。

stage = "prod"

画像で表すとこのようになります。

この状態で terraform apply を実行します。

terraform apply
⚠️ terraform.tfvarsの値が反映されない場合
ファイル名が正確にterraform.tfvarsになっているか確認してください(terraform.tfvar(sなし)やvariables.tfvarsなどは自動で読み込まれません)。
また、ファイルがmain.tfと同じディレクトリに存在するか確認してください。

main.tf には default = "test" と書かれていますが、terraform.tfvars の値が優先され、prod-vpc として作成される計画が表示されます。

2.4 リソースの削除

確認ができたら、作成されたリソースを削除しておきましょう。

terraform destroy