条件分岐

条件によって属性の設定値を変更できる、Terraformにおける if 文の実現方法について解説します。

1. 概要

1.1 条件分岐の基本

Terraformには、一般的なプログラミング言語にあるような if ブロック(if (条件) { ... })は存在しません。その代わりに、「三項演算子」(Ternary Operator)という仕組みを使って条件分岐を実現します。

2. 記載方法

条件 ? trueの場合の値 : falseの場合の値
  • ? の前: 条件式(true または false になるもの)
  • ? と : の間: 条件が true の時に使われる値
  • : の後ろ: 条件が false の時に使われる値

2.1 パターン1:設定値の切り替え

例えば、環境(本番/開発)によって、スペックなどの設定値を切り替えたい場合によく使います。

以下の例は、EC2インスタンスのインスタンスタイプを、テスト環境と本番環境で切り分けたい場合の例です。stage という variables の値を元に、本番であれば t3.micro、それ以外の場合は性能の低い t2.micro を設定しています。

instance_type = var.stage == "prod" ? "t3.large" : "t2.micro"

2.2 パターン2:リソース作成のON/OFF(countとの組み合わせ)

count と組み合わせることで、「条件を満たす時だけリソースを作成する」(if create)という制御が可能になります。

仕組みは単純です。

  • 条件が true なら count = 1(1つ作る)
  • 条件が false なら count = 0(作らない)

このように、「作る数を0にする」ことで「作らない」を実現します。

resource "aws_s3_bucket" "log_bucket" {
  # フラグが true なら 1個作成、false なら 0個(作成しない)
  count = var.enable_logging ? 1 : 0

  bucket = "my-log-bucket-12345"
}

この方法は、Terraformで「リソースを作るか作らないかを動的に制御したい」ときによく使われます。

3. 実際に使ってみる(ハンズオン)

それでは、実際に条件分岐を行っていきましょう。まずは、シンプルに「値の設定を切り分ける」例です。

3.1 リソースの値の判定

先ほどのEC2インスタンスのインスタンスタイプの例でも良いのですが、EC2インスタンスは作成する関連リソースが多く複雑になるため、今回は「VPCのCIDRブロック」を制御してみたいと思います。

var.stage が「prod」であれば「10.0.0.0/16」、それ以外の場合は「10.1.0.0/16」とするように制御してみます。

provider "aws" {
  region = "ap-northeast-1"
}

variable "stage" {
  description = "環境名 (例: prod, dev)"
  type        = string
  default     = "prod"
}

resource "aws_vpc" "main" {
  cidr_block = var.stage == "prod" ? "10.0.0.0/16" : "10.1.0.0/16"

  tags = {
    Name = "handson-vpc-${var.stage}"
  }
}

作成されたリソースをみていきます。handson-vpc-prod というVPCが作成され、CIDRブロックが 10.0.0.0/16 となっていればOKです。

続いて、Variable で定義した stage の default 値を、prod → test に変えて実行してみましょう。

⚠️ terraform.tfvars が残っている場合
前のセクション(変数の利用)で terraform.tfvars に stage = "prod" を記載した場合、terraform.tfvars の値は default より優先されるため、default を変更しても反映されません。terraform.tfvars 内の stage の行を削除するか、ファイル自体を削除してから実行してください。
variable "stage" {
  description = "環境名 (例: prod, dev)"
  type        = string
  default     = "test"
}

すると、CIDRブロックが 10.1.0.0/16 で作成されます。

確認が終わったらリソースを削除しておきましょう。

terraform destroy

3.2 リソースの作成判断

続いて、条件判定と count を組み合わせて、リソースの作成判断を行っていきます。下記は、stage が prod であればVPCを作成、それ以外の場合は作成しないという制御を行っています。

provider "aws" {
  region = "ap-northeast-1"
}

variable "stage" {
  description = "環境名 (例: prod, dev)"
  type        = string
  default     = "prod"
}

resource "aws_vpc" "main" {
  count = var.stage == "prod" ? 1 : 0

  cidr_block = "10.0.0.0/16"

  tags = {
    Name = "handson-vpc-${var.stage}"
  }
}

実際にリソースを作成してみましょう

terraform apply

handson-vpc-prod というリソースが作成されていれば、ここまではOKです。

続いて、variables で定義している stage の default 値を、test に変更します。

variable "stage" {
  description = "環境名 (例: prod, dev)"
  type        = string
  default     = "test"
}

再度リソースを作成してみましょう

terraform apply

VPCが削除(あるいは作られない)されていることを確認します。