for_each

count は「回数(数字)」を指定してリソースを作りましたが、for_each は「Map」(キーと値のペア)や「Set」(文字列の集合)を元にリソースを作成します。

1. 概要

count は「回数(数字)」を指定してリソースを作りましたが、for_each は「Map」(キーと値のペア)や「Set」(文字列の集合)を元にリソースを作成します。

count との最大の違いは、リソースの管理方法です。

  • count: インデックス番号(0, 1, 2...)で管理
  • for_each: キー(名前などの文字列)で管理

これにより、リストの途中の要素を削除しても、インデックスずれによる意図しないリソースの再作成を防ぐことができるため、より安全に運用できます。

2. 記載方法

リソースブロックの中に for_each を記述し、ループさせたいデータ(MapやSet)を渡します。

ブロック内では以下のオブジェクトを使って値を参照できます。

  • each.key: 現在のループのキー(Mapのキー、またはSetの文字列そのもの)
  • each.value: 現在のループの値(Mapの値、Setの場合はキーと同じ)
resource "リソース型" "名前" {
  for_each = {
    キー1 = "値1"
    キー2 = "値2"
  }

  属性1 = each.key   # キーを参照
  属性2 = each.value # 値を参照
}

3. サンプルコード

例えば、「Taro」と「Jiro」という二つのユーザを作り、タグとして「Admin、Developer」が入るMapを使うと綺麗に書けます。

resource "aws_iam_user" "users" {
  # ユーザ名(Key)と、タグに入れる役割(Value)を定義
  for_each = {
    Taro = "Admin"
    Jiro   = "Developer"
  }

  name = each.key # Taro, Jiro が入る

  tags = {
    Role = each.value # Admin, Developer が入る
  }
}

このコードを実行すると、aws_iam_user.users["Taro"] と aws_iam_user.users["Jiro"] という、名前をキーにしたリソースが作成されます。

4. 実際に使ってみる(ハンズオン)

4.1 実行例1

ここでは、シンプルなMapを使って、特定の名前を持つIAMユーザを作成してみましょう。

main.tf を以下のように書き換えてください。

provider "aws" {
  region = "ap-northeast-1"
}

resource "aws_iam_user" "users" {
  for_each = {
    Taro = "Admin"
    Jiro   = "Developer"
  }

  name = each.key

  tags = {
    Role = each.value
  }
}

リソースを作成してみます

terraform apply

実行プランを確認すると、count の時のような [0] ではなく、文字列が識別子になっていることがわかります。

aws_iam_user.users["Taro"]
aws_iam_user.users["Jiro"]

yes で適用し、AWSコンソールで2名のユーザが作成されていることを確認しましょう。

確認が終わったら、リソースを削除しておきましょう。

terraform destroy

5. count と for_each の使い分け

機能 特徴 向いているケース
count インデックス(0,1,2)で管理 単純なコピー。中身に個性がない場合。例:同じ構成のサブネットを2つ作る、AZごとに1つ作る等。
for_each キー(文字列)で管理 個別の設定が必要な場合。順序が変わる可能性がある場合。例:ユーザ作成、特定の設定値を持つリソース作成。

基本的には、「単純な数合わせならcount、個別の管理が必要ならfor_each」と覚えておくとよいです。

count と for_each の詳しい仕様や注意点は、Terraform公式ドキュメントのThe count Meta-ArgumentとThe for_each Meta-Argumentに記載があります。